Date and time computations with GAMAP

Date and time

Julian Day vs. Astronomical Julian Day

The Julian Day (JD) is used to denote the number of days that have elapsed since the start of a year. For example, the Julian Day number of 2008/01/10 is 10 (since it is the 10th day of 2008).

However, another term that is sometimes confused with the Julian Day is the Astronomical Julian Day (AJD). This is the number of days that have elapsed since 12:00 GMT on January 1, 4713 BC. The Astronomical Julian Day at 00:00 GMT on 2008/01/10 is 2454475.5.

The Astronomical Julian Day is mostly used in astrophysics and space sciences to compute long intervals of time that may span many years (e.g. the period of a variable star or of a comet's orbit, etc.). You can find algorithms for computing AJD in several textbooks, including Practical Astronomy with Your Calculator by Peter Duffett-Smith, Cambridge Univ. Press, 1992.

The chief advantage of using the Astronomical Julian Day is that its computation accounts for the end-of-month, end-of-year, end-of-century, and end-of-millenium transitions. This makes it very useful for computing future or past dates in scripts and computer programs.

For example, if you want to compute what the date will be 1000 days from 2008/01/01, then all you have to do is:

1. compute the Astronomical Juliay Day for 2008/01/01
2. add 1000
3. convert back to a calendar date

We'll return to this example in the next section.

TIP: In order to avoid confusing Julian Day with Astronomical Julian Day, we recommend that you use the terminology "Day of Year" rather than "Julian Day". This will remove all ambiguity.

Astronomical Julian Day routines in IDL and GAMAP

IDL has two Astronomical Julian Day functions

• JULDAY -- converts a year, month, day (, hour, min, sec) to Astronomical Julian Date
• CALDAT -- converts an Astronomical Julian Day back to year, month, day (, hour, min, sec)

NOTE: The year, month, day are mandatory but you may omit the hour, min, sec. If you omit hour, min, sec, then JULDAY will return an long integer value. If you include hour, min, sec, JULDAY wil return a double precision value.

JULDAY and CALDAT are used as follows:

; Compute the Astronomical Julian Day for 2008/01/10
; Note: the day is required, the hours, mins, seconds are optional
IDL> print, julday( 1, 10, 2008, 0, 0, 0 )
       2454475.5

; Convert the Astronomical Julian Day back to a calendar date
IDL> caldat, 2454475.5, y, m, d, h, mi, s
IDL> print, y, m, d, h, mi, s
           1          10        2008           0           0       0.0000000

To compute the date 1000 days after 2008/01/01 (from the example in the preceding section), you would do the following:

IDL> jd = julday( 1, 1, 2008 ) 
IDL> jd = jd + 1000
IDL> caldat, jd, y, m, d
IDL> print, y, m, d
          9          27        2010

We find that gives us the date 2010/09/27. NOTE: This has also accounted for the leap-year-day on Feb 29, 2008.

For your convenience, GAMAP has a function called ADD_DATE which will do this for you in one fell swoop:

IDL> print, add_date( 20080101, 1000 )
    20100927

You can also use ADD_DATE to compute days prior to a given date. Let's compute what the calendar date was 1000 days prior to Jan 1, 2008:

IDL> print, add_date( 20080101, -1000 )
    20050406

Computing the day of year from a calendar date (and vice-versa)

A quick way to compute the day of the year is w/ IDL's JULDAY function:

Day_of_Year = JULDAY( Month, Day, Year ) - JULDAY( 1, 0, Year )

For example:

IDL> print, julday( 1, 10, 2008 ) - julday( 1, 0, 2008 )
      10

JULDAY( 1, 0, 2008 ) is another way of saying 12/31/2007. This is used so that you don't have to add one to the above equation. (This is equivalent to JULDAY( 1, 10, 2008 ) - JULDAY( 1, 1, 2008 ) + 1.)

The GAMAP function DAY_OF_YEAR does the above computation for you. You can replace the statement above with:

IDL> print, day_of_year( 1, 10, 2008 )
      10

To compute the calendar date from the day of the year (the inverse operation), you can use IDL's CALDAT function. However, you must also add the Astronomical Julian day for the first of the year, for example:

IDL> caldat, julday( 1, 0, 2008 )+10, y, m, d
IDL> print, y, m, d
        1          10        2008

But this is made much easier with the GAMAP functions DAY_OF_YEAR and ADD_DATE:

; Convert month/day/year to day of year
IDL> doy = day_of_year( 1, 10, 2008 )
IDL> print, doy
      10

; convert day of year back to month/day/year
IDL> print, add_date( 20080101, doy-1 )
    20080110

The only thing to remember is you have to subtract 1 from the day of year due to the way that ADD_DATE is written.

NOTE: Starting in GAMAP v2-12 (not released yet), you will be able to specify a single YYYYMMDD argument instead of the month, day, year arguments:

; Convert month/day/year to day of year
IDL> doy = day_of_year( 20080110 )

Working with TAU values

Conceptually similar to the Astronomical Julian Day, the TAU value is a monotonically-increasing time index that is used to timestamp output from the GEOS-Chem and GISS models:

• GEOS-Chem: TAU is the count of hours since 0 GMT on Jan 1, 1985
• GISS: TAU is the count of hours since 0 GMT on Jan 1, 1980

However, unlike the Astronomical Julian Day, TAU is given in hours and not days. Also, the reason for the difference in starting date for TAU is that at the time GEOS-Chem was being created, there existed no meteorological data for it prior to Jan 1, 1985. So 1/1/85 was taken as the start date.

GAMAP ships with 2 functions for working with TAU values: NYMD2TAU and TAU2YYMMDD. They are used as follows:

; Convert a date and time to TAU 
; GEOS-Chem style (from 1985) is the default
IDL> tau_gc = nymd2tau( 20080101, 030000 )
IDL> print, tau_gc
      201603.00

; Convert TAU back to date and time (GEOS-Chem style)
IDL> date = tau2yymmdd( tau_gc, /nformat )
IDL> print, date
   20080101       30000

Note that TAU2YYMMDD returns a 2-element vector with the date and time when you use the /NFORMAT keyword. If you omit this keyword then TAU2YYMMDD will return a structure with year, month, day, hour, minute, second tags:

; Convert TAU back to date and time (GEOS-Chem style)
; but this time return as a structure
IDL> date = tau2yymmdd( tau_gc )
IDL> help, date, /structure
** Structure <2061898>, 6 tags, length=24, data length=24, refs=1:
   YEAR            LONG      Array[1]
   MONTH           LONG      Array[1]
   DAY             LONG      Array[1]
   HOUR            LONG      Array[1]
   MINUTE          LONG      Array[1]
   SECOND          LONG      Array[1]

NYMD2TAU and TAU2YYMMDD assume GEOS-Chem style (from 1 Jan 1985) as the default. To compute TAU for GISS style (from 1 Jan 1980), you can call these functions with the /GISS keyword as follows:

; Convert date to TAU value (GISS style)
IDL> tau_giss = nymd2tau( 20080101, 030000, /giss )
IDL> print, tau_giss
      245451.00

; Convert TAU value back to date (GISS style)
IDL> date = tau2yymmdd( tau_giss, /nformat, /giss )
IDL> print, date
    20080101       30000

Separating YYYYMMDD into year, month day

GAMAP ships with 2 routines which make it easy to extract (or combine) the year, month, day from (to) a date in YYYYMMDD format: DATE2YMD and YMD2DATE:

; Split 20080101 into separate year, month, day variables
IDL> date2ymd, 20080101, y, m, d
IDL> print, y, m, d
       2008           1           1

; Combine year, month, day variables into YYYYMMDD format
IDL> date = ymd2date( 2008, 1, 1 )                   
IDL> print, date
    20080101

You can also use DATE2YMD and YMD2DATE with times in HHMMSS format:

; Split the time 12:30:45 into separate hour, min, sec variables
IDL> date2ymd, 123045, hour, min, sec
IDL> print, hour, min, sec
         12          30          45

; Combine 12h, 30min, 45sec into a single time variable
IDL> time = ymd2date( 12, 30, 45 )
IDL> print, time
      123045

--Bmy 09:56, 4 April 2008 (EDT)